Министерство науки и высшего образования Российской Федерации Федеральное государственное автономное образовательное учреждение высшего образования

«Национальный исследовательский университет ИТМО»

Факультет программной инженерии и компьютерной техники

**Лабораторная работа №6**

по дисциплине «Основы профессиональной деятельности»

**Обмен данными с ВУ по прерыванию**

Вариант №84123

Группа: P3112

Выполнил: Балин А. А.

Проверил: Осипов С. В.

# Оглавление

[Введение 2](#_Toc136529870)

[Задание 3](#_Toc136529871)

[Текст программы 4](#_Toc136529872)

[Методика проверки программы 7](#_Toc136529873)

[Задание на защиту 9](#_Toc136529874)

[Заключение 10](#_Toc136529875)

[Список литературы 11](#_Toc136529876)


# Введение

В данной лабораторной работе я изучу работу с прерываниями в БЭВМ.

# Задание

По выданному преподавателем варианту разработать и исследовать работу комплекса программ обмена данными в режиме прерывания программы. Основная программа должна изменять содержимое заданной ячейки памяти (Х), которое должно быть представлено как знаковое число. Область допустимых значений изменения Х должна быть ограничена заданной функцией F(X) и конструктивными особенностями регистра данных ВУ (8-ми битное знаковое представление). Программа обработки прерывания должна выводить на ВУ модифицированное значение Х в соответствии с вариантом задания, а также игнорировать все необрабатываемые прерывания.

Программа по моему варианту



# Текст программы

ORG 0x0

V0: WORD $DEFAULT, 0x180

V1: WORD $INT1, 0x180

V2: WORD $DEFAULT, 0x180

V3: WORD $INT3, 0x180

V4: WORD $DEFAULT, 0x180

V5: WORD $DEFAULT, 0x180

V6: WORD $DEFAULT, 0x180

V7: WORD $DEFAULT, 0x180

ORG 0x039

X: WORD 0x0             ; наше X в ячейке памяти 0x039

DEFAULT: IRET

MIN\_VALUE: WORD 0xFFEC  ;-20 минимальное значение по ОДЗ

MAX\_VALUE: WORD 0x16    ; 22 максимальное значение по ОДЗ

ADDR: WORD $X           ;адрес ячейки X

START:

    DI          ; запрет прерываний

    CLA

    LD #0x9     ; MR1 -> AC (1000|0001 -> 1001)

    OUT 3       ; разрешить прерывание на ВУ-1

    LD #0xB     ; MR3 -> AC (1000|0011 -> 1011)

    OUT 7       ; разрешить прерывания на ВУ-3

T1: WORD ?

PROG: EI        ; разрешить прерывания

    CLA

    INC\_LOOP:

        LD $X

        ST $T1

        INC

        CALL $CHECK\_X

        PUSH

        LD $T1

        PUSH

        LD $ADDR

        PUSH

        CALL $CAS

        SWAP

        POP

        SWAP

        POP

        SWAP

        POP

        JUMP $INC\_LOOP

CHECK\_X:

    CMP $MAX\_VALUE

    BPL SET\_MIN

    CMP $MIN\_VALUE

    BMI SET\_MIN

    RET

    SET\_MIN:

        LD $MIN\_VALUE

        RET

T2: WORD ?

INT1:

    HLT

    PUSH

    ST $T2

    ADD $T2

    ADD $T2         ;x3

    ASL             ;x3 x2 = x6

    SUB #8

    OUT 2

    POP

    HLT

    IRET

Y3: WORD ?

INT3:

    HLT

    PUSH

    CLA

    IN 6

    ST $Y3

    CLA

    SUB $Y3

    SUB $Y3

    SUB $Y3

    ADD $X

    ST $X

    POP

    HLT

    IRET

DEREF: WORD ?

CAS: ;PS-0, RET - 1, ADR - 2, OLD\_VALUE - 3, FUNC\_VALUE - 4

    PUSHF

    DI

    LD &2

    ST $DEREF

    LD &3

    CMP (DEREF)

    BNE OUT\_CAS

    LD &4

    ST (DEREF)

    OUT\_CAS: POPF

    RET

ОДЗ

X – знаковое число, причем -128<=6х-8<128, -20<x<22.

# Методика проверки программы

Проверка обработки прерываний:

1. Загрузить текст программы в БЭВМ.

2. Заменить все NOP на HLT.

3. Запустить программу в автоматическом режиме с адреса 0x03D

4. Установить «Готовность ВУ-1».

5. Дождаться останова.

6. Записать текущее значение X из памяти БЭВМ:

* Запомнить текущее состояние счетчика команд.
* Ввести в клавишный регистр значение 0x039
* Нажать «Ввод адреса».
* Нажать «Чтение».
* Записать значение регистра данных.
* Вернуть счетчик команд в исходное состояние.

7. Записать результат обработки прерывания – содержимое DR КВУ-1

8. Рассчитать ожидаемое значение обработки прерывания

9. Нажать «Продолжение».

10. Ввести в ВУ-3 произвольное число

11. Установить «Готовность ВУ-3».

12. Дождаться останова.

13. Записать текущее значение X из памяти БЭВМ (аналогично п.6).AC(0..7)

14. Нажать «Продолжение».

15. Записать текущее значение X из памяти БЭВМ (аналогично п.6).AC(0..7)

16. Рассчитать ожидаемое значение переменной X после обработки прерывания.

17. Проверить, что при выходе значения X за ОДЗ оно сбрасывается на минимальное.

|  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- |
| Прерывание ВУ-1 | | | Прерывание ВУ-3 | | | |
| AC (0..7) | 6x-8 | DR | AC (0..7) | DR КВУ-3 | AC(X-3\*DR) | Результат AC(0..7) |
| 1 | -2 | FE | 6 | 3 | -3 | FFFD = -3 |
| 8 | 28 | 1C | 1 | 2 | -5 | FFFB = -5 |
| 18 | 100 | 100 | 12 | 4 | 0 | 0 |
| -20 | -128 | -128 | 15 | 4 | 3 | 3 |

# Задание на защиту

Таймер на ВУ-7 с поддержкой 4 разрядов (1 для минут, 1 для пропуска и 2 для секунд), с возможность смещения относительно начала влево (крайнее правое положение – 0, крайнее левое – 4) с помощью ВУ-2. Количество секунд вводится с помощью ВУ-3 при старте программы, а при нажатии кнопки на ВУ-1 таймер превращается в секундомер и начинает считать в обратную сторону!

ORG 0x000

V0: WORD $INT0, 0x180

V1: WORD $INT1, 0x180

V2: WORD $INT2, 0x180

V3: WORD $DEFAULT, 0x180

V4: WORD $DEFAULT, 0x180

V5: WORD $DEFAULT, 0x180

V6: WORD $DEFAULT, 0x180

V7: WORD $DEFAULT, 0x180

DEFAULT: IRET

T0: WORD 0x000B

T1: WORD 0x001B

T2: WORD 0x002B

T3: WORD 0x003B

T4: WORD 0x004B

T5: WORD 0x005B

T6: WORD 0x006B

TS: WORD 0x0000

TIME: WORD ?

START:

    DI

    CLA

    LD #0x8     ;прерывание

    OUT 0x1       ;на ВУ-0

    LD #0x9     ;прерывание

    OUT 3      ;на ВУ-1

    LD #0xA     ;прерывание

    OUT 0x5      ;на ВУ-2

    EI

TIMER\_TIME\_SET: IN 0x7

    AND #0x40

    BEQ TIMER\_TIME\_SET

    IN 0x6

    ST $TIME

    LD #0xA

    OUT 0

    JUMP $MAIN

T: WORD ?

COUNT: WORD ?

TEMP: WORD ?

HLTT: HLT

MAIN:

    LD $TIME

    CMP $T

    BEQ MAIN

    LD $TIME

    ST $T

    ST $TEMP

    CLA

    ST $COUNT

    MINUS\_60:

    LD $TEMP

    SUB #60

    ST $TEMP

    BMI GOT\_MIN

    LD $COUNT

    INC

    ST $COUNT

    JUMP $MINUS\_60

    GOT\_MIN:

    LD $COUNT

    ADD #0x30

    ST $T3

    LD #0x2B

    ST $T2

    LD $TEMP

    ADD #60

    ST $TEMP

    CLA

    ST $COUNT

    GET\_SEC: LD $TEMP

    SUB #10

    ST $TEMP

    BMI GOT\_SEC

    LD $COUNT

    INC

    ST $COUNT

    JUMP $GET\_SEC

    GOT\_SEC: LD $COUNT

    ADD #0x10

    ST $T1

    LD $TEMP

    ADD #10

    ST $T0

    CALL $OUTP0

    LD $TIME

    BEQ HLTT

    JUMP $MAIN

OUTP0:

    CLA

    PUSH

    PUSH

    LD $TS

    BEQ CLEARING

    ASL

    ASL

    ASL

    ASL

    ST &1

    CLEARING: IN 0x15

    AND #0x40

    BEQ CLEARING

    LD &0

    ADD #0xB

    OUT 0x14

    ADD #5

    ST &0

    CMP #0x7D

    BMI CLEARING

    OUTP1: IN 0x15

    AND #0x40

    BEQ OUTP1

    LD $T3

    ADD &1

    OUT 0x14

    OUTP2: IN 0x15

    AND #0x40

    BEQ OUTP2

    LD $T1

    ADD &1

    OUT 0x14

    OUTP3: IN 0x15

    AND #0x40

    BEQ OUTP3

    LD $T0

    ADD &1

    OUT 0x14

    SWAP

    POP

    SWAP

    POP

    RET

DIRECTION: WORD 0xFFFF

INT2:

    NOP

    PUSH

    CLA

    IN 0x4

    CMP #5

    BPL INT0\_IRET

    ST $TS

    INT0\_IRET: POP

    NOP

    IRET

INT1:

    NOP

    PUSH

    LD $DIRECTION

    NEG

    OUT 2

    ST $DIRECTION

    POP

    NOP

    IRET

INT0:

    NOP

    PUSH

    LD #0xA

    OUT 0

    LD $TIME

    ADD $DIRECTION

    ST $TIME

    POP

    NOP

    IRET

# Заключение

Я изучил работу БЭВМ с различными ВУ по прерываниям.

# Список литературы

**Методические указания к лабораторным работам по курсу "Основы профессиональной деятельности"** [В Интернете] / авт. В. В. Кириллов А. А. Приблуда, С. В. Клименков, Д. Б. Афанасьев. - https://se.ifmo.ru/documents/10180/38002/Методические+указания+к+выполнению+лабораторных+работ+и+рубежного+контроля+БЭВМ+2019+bcomp-ng.pdf/d5a1be02-ad3f-4c43-8032-a2a04d6db12e.